SX 03a: TX ACK

This example shows how to configure the semtech module in LoRa mode and then send packets with plain-text payloads waiting for the acknowledgement (ACK) from the receiver

Required Materials

1 x Waspmote PRO 1 x Battery 1 x MiniUSB wire 1 x SX1272 module (LoRa) 1 x Receiver module with SX_03b example

Notes

- The SX1272 module is provided with a special 4.5 dBi antenna, which enables maximum range. The only exception is Smart Parking; in this case the antenna is smaller, 0 dBi, to fit inside the enclosure. - It is not recommended to work without an antenna screwed to the module. The module could be damaged due to RF reflections. - The SX1272 module can only be used in special Waspmote units which have been modified to drive the SPI pins to SOCKET0. (only SOCKET0 is available for SX1272) - This module does not save the configuration. So, the network settings as the mode or the channel MUST be configured every time it is switched on. - This example can be executed in Waspmote v12 and Waspmote v15

Code

/*
 *  ------ [SX_03a] - TX LoRa with ACKs -------- 
 *
 *  Explanation: This example shows how to configure the semtech 
 *  module in LoRa mode and then send packets with plain-text payloads
 *  waiting for the acknowledgement (ACK) from the receiver
 *
 *  Copyright (C) 2014 Libelium Comunicaciones Distribuidas S.L. 
 *  http://www.libelium.com 
 *  
 *  This program is free software: you can redistribute it and/or modify 
 *  it under the terms of the GNU General Public License as published by 
 *  the Free Software Foundation, either version 3 of the License, or 
 *  (at your option) any later version. 
 *  
 *  This program is distributed in the hope that it will be useful, 
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of 
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the 
 *  GNU General Public License for more details. 
 *  
 *  You should have received a copy of the GNU General Public License 
 *  along with this program.  If not, see . 
 *  
 *  Version:           0.1
 *  Design:            David Gascón 
 *  Implementation:    Covadonga Albiñana, Yuri Carmona
 */


// Include this library to transmit with sx1272
#include <WaspSX1272.h>

// define the destination address to send packets
uint8_t rx_address = 2;

// status variable
int8_t e;


void setup()
{
  // Init USB port
  USB.ON();
  USB.println(F("SX_03a example"));
  USB.println(F("Semtech SX1272 module TX in LoRa with ACKs"));

  USB.println(F("----------------------------------------"));
  USB.println(F("Setting configuration:")); 
  USB.println(F("----------------------------------------"));

  // Init sx1272 module
  sx1272.ON();

  //// Options to configure: ////

  // Select frequency channel
  e = sx1272.setChannel(CH_14_868);
  USB.print(F("Setting Channel CH_14_868.\t state ")); 
  USB.println(e);

  // Select implicit (off) or explicit (on) header mode
  e = sx1272.setHeaderON();
  USB.print(F("Setting Header ON.\t\t state "));  
  USB.println(e); 

  // Select mode: from 1 to 10
  e = sx1272.setMode(10);  
  USB.print(F("Setting Mode '10'.\t\t state ")); 
  USB.println(e);  
  
  // Select CRC on or off
  e = sx1272.setCRC_ON();
  USB.print(F("Setting CRC ON.\t\t\t state "));
  USB.println(e); 

  // Select output power (Max, High or Low)
  e = sx1272.setPower('H');
  USB.print(F("Setting Power to 'H'.\t\t state "));  
  USB.println(e); 

  // Select the node address value: from 2 to 255
  e = sx1272.setNodeAddress(7);
  USB.print(F("Setting Node Address to '7'.\t state "));
  USB.println(e);
  USB.println();

  delay(1000);  

  USB.println(F("----------------------------------------"));
  USB.println(F("Sending:")); 
  USB.println(F("----------------------------------------"));
}


void loop()
{
  // Sending packet before ending a timeout and waiting for an ACK response  
  e = sx1272.sendPacketTimeoutACK(rx_address, "this_is_the_data_message");

  // Check sending status
  if( e == 0 ) 
  {
    USB.println(F("Packet sent OK"));     
  }
  else 
  {
    USB.print(F("Error sending the packet."));  
    USB.print(F("state: "));
    USB.println(e, DEC);
  } 

  delay(1000);
}

Output

H#
SX_03a example
Semtech SX1272 module TX in LoRa with ACKs
----------------------------------------
Setting configuration:
----------------------------------------
Setting Channel CH_14_868. state 0
Setting Header ON. state 0
Setting Mode '10'. state 0
Setting CRC ON. state 0
Setting Power to 'H'. state 0
Setting Node Address to '7'. state 0

----------------------------------------
Sending:
----------------------------------------
Packet sent OK
Packet sent OK
Packet sent OK
...